正文

易语言多线程多任务下载器的代码

︶ㄣSDDLL学院 メ
SDDLL学院V管理员 / 阅读
0707
今天小编就为大家分享一篇关于易语言多线程多任务下载器的代码，小编觉得内容挺不错的，现在分享给大家，具有很好的参考价值，需要的朋友一起跟随小编来看看吧

今天小编就为大家分享一篇关于易语言多线程多任务下载器的代码，小编觉得内容挺不错的，现在分享给大家，具有很好的参考价值，需要的朋友一起跟随小编来看看吧

多线程多任务下载模块源码

1.DLL命令表

?
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
.版本 2
.DLL命令 InternetGetConnectedStateHTTP, , "Wininet.dll", "InternetGetConnectedState", 公开
  .参数 lpdwFlags, 整数型, 传址
  .参数 dwReserved, 整数型
.DLL命令 InternetOpenAHTTP, 整数型, "Wininet.dll", "InternetOpenA", 公开
  .参数 lpszAgent, 文本型
  .参数 dwAccessType, 整数型
  .参数 lpszProxyName, 整数型
  .参数 lpszProxyBypass, 整数型
  .参数 dwFlags, 整数型
.DLL命令 InternetOpenUrlAHTTP, 整数型, "Wininet.dll", "InternetOpenUrlA", 公开
  .参数 hInternet, 整数型
  .参数 lpszUrl, 文本型
  .参数 lpszHeaders, 文本型
  .参数 dwHeadersLength, 整数型
  .参数 dwFlags, 整数型
  .参数 dwContext, 整数型
.DLL命令 InternetCloseHandleHTTP, , "Wininet.dll", "InternetCloseHandle", 公开
  .参数 handle, 整数型
.DLL命令 HttpQueryInfoAHTTP, 整数型, "Wininet.dll", "HttpQueryInfoA", 公开
  .参数 hRequest, 整数型
  .参数 dwInfoLevel, 整数型
  .参数 lpvBuffer, 整数型, 传址
  .参数 lpdwBufferLength, 整数型, 传址
  .参数 lpdwIndex, 整数型, 传址
.DLL命令 创建文件, 整数型, "kernel32.dll", "CreateFileA", 公开
  .参数 文件名, 文本型
  .参数 打开方式, 整数型, , -2147483648表示读，1073741824表示写，0可取属性
  .参数 共享方式, 整数型, , 1共享读，2共享写，0不共享
  .参数 安全性, 整数型, , 为空即可
  .参数 打开方式2, 整数型, , 1创建文件（文件存在出错），2创建文件（改写），3文件必须存在，4如果文件不存在则创建，5将现有文件缩短为0
  .参数 文件属性, 整数型, , 128默认属性，268435456随机访问优化，134217728连续访问优化，67108864临时文件
  .参数 文件句柄, 整数型, , 一般为0
.DLL命令 创建映射, 整数型, "kernel32.dll", "CreateFileMappingA", 公开
  .参数 文件句柄, 整数型
  .参数 安全对象, 整数型, , 0表示默认属性
  .参数 映射方式, 整数型, , 2表示只读，4表示可读写
  .参数 高32位, 整数型, , 文件映射的最大长度（高32位）
  .参数 低32位, 整数型, , 文件映射的最小长度（低32位）
  .参数 对象名字, 整数型, , 可以更改为文件型
.DLL命令 映射装载, 整数型, "kernel32.dll", "MapViewOfFile", 公开
  .参数 映射句柄, 整数型
  .参数 映射方式, 整数型, , 2可读可写,4只读,
  .参数 高32位, 整数型, , 文件中映射起点的高32位地址，64k的整数倍
  .参数 低32位, 整数型, , 文件中映射起点的低32位地址，64k的整数倍
  .参数 字节数, 整数型, , 文件中要映射的字节数，根据实际长度指定
.DLL命令 映射卸载, 整数型, "kernel32.dll", "UnmapViewOfFile", 公开
  .参数 映射地址, 整数型, , 用映射装载函数获得的
.DLL命令 CloseHandleHTTP, 整数型, "kernel32.dll", "CloseHandle", 公开
  .参数 hObject, 整数型
.DLL命令 HeapCreate, 整数型, "kernel32.dll", "HeapCreate", 公开
  .参数 flOptions, 整数型
  .参数 dwInitialSize, 整数型
  .参数 dwMaximumSize, 整数型
.DLL命令 HeapAllocHTTP, 整数型, "kernel32.dll", "HeapAlloc", 公开
  .参数 hHeap, 整数型
  .参数 dwFlags, 整数型
  .参数 dwBytes, 整数型
.DLL命令 HeapDestroy, 逻辑型, "kernel32.dll", "HeapDestroy", 公开
  .参数 hHeap, 整数型
.DLL命令 RtlMoveMemory_读整数, , "kernel32.dll", "RtlMoveMemory", 公开
  .参数 Destination, 整数型, 传址
  .参数 Source, 整数型
  .参数 Length, 整数型
.DLL命令 RtlMoveMemory_写整数, , "kernel32.dll", "RtlMoveMemory", 公开
  .参数 Destination, 整数型
  .参数 Source, 整数型, 传址
  .参数 Length, 整数型
.DLL命令 RtlMoveMemory_写文本, , "kernel32.dll", "RtlMoveMemory", 公开
  .参数 Destination, 整数型
  .参数 Source, 文本型, 传址
  .参数 Length, 整数型
.DLL命令 InitializeCriticalSectionHTTP, , "kernel32.dll", "InitializeCriticalSection", 公开
  .参数 lpCriticalSection, 整数型
.DLL命令 CreateThreadHTTP, 整数型, "kernel32.dll", "CreateThread", 公开
  .参数 lpThreadAttributes, 整数型
  .参数 dwStackSize, 整数型
  .参数 lpStartAddress, 子程序指针
  .参数 lpParameter, 整数型
  .参数 dwCreationFlags, 整数型
  .参数 lpThreadId, 整数型, 传址
.DLL命令 DeleteCriticalSectionHTTP, , "kernel32.dll", "DeleteCriticalSection", 公开
  .参数 lpCriticalSection, 整数型
.DLL命令 EnterCriticalSectionHTTP, , "kernel32.dll", "EnterCriticalSection", 公开
  .参数 lpCriticalSection, 整数型
.DLL命令 LeaveCriticalSectionHTTP, , "kernel32.dll", "LeaveCriticalSection", 公开
  .参数 lpCriticalSection, 整数型
.DLL命令 WaitForSingleObjectHTTP, 整数型, "kernel32.dll", "WaitForSingleObject", 公开
  .参数 hHandle, 整数型
  .参数 dwMilliseconds, 整数型
.DLL命令 InternetReadFileHTTP, 整数型, "Wininet.dll", "InternetReadFile", 公开
  .参数 hFile, 整数型
  .参数 lpBuffer, 整数型
  .参数 dwNumberOfBytesToRead, 整数型
  .参数 lpdwNumberOfBytesRead, 整数型, 传址
.DLL命令 写入映射, , "kernel32.dll", "RtlMoveMemory", 公开
  .参数 起始位置, 整数型, , 用映射装载命令得到的
  .参数 待写入数据, 整数型, , 要写入的数据，可以更改为其他类型
  .参数 数据长度, 整数型, , 要写入的数据长度，不大于实际数据长度
.DLL命令 HeapFree, 逻辑型, "kernel32.dll", "HeapFree", 公开
  .参数 hHeap, 整数型
  .参数 dwFlags, 整数型
  .参数 lpMem, 整数型
.DLL命令 PathFindExtensionAjtw, 文本型, "shlwapi.dll", "PathFindExtensionA", 公开
  .参数 文件路径, 文本型
.DLL命令 InternetGetConnectedState, 逻辑型, "Wininet.dll", "InternetGetConnectedState", 公开, 本来是无返回值
  .参数 lpdwFlags, 整数型, 传址
  .参数 dwReserved, 整数型
.DLL命令 HttpQueryInfohx, 整数型, "wininet.dll", "HttpQueryInfoA", 公开
  .参数 Internet请求句柄, 整数型
  .参数 待查信息, 整数型
  .参数 返回容器, 文本型, 传址
  .参数 返回容器长度, 整数型, 传址
  .参数 lpdwIndex, 整数型, 传址

2.全局变量表

?
1
2
3
.版本 2
.全局变量 配备文本变量, 文本型, , "0"
.全局变量 多任务句柄, 整数型, , "0"

3.多线程

?
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
.版本 2
.程序集 程序集2
.子程序 文件_取网络文件名1, 文本型, 公开
.参数 地址, 文本型
.局部变量 Onlined, 逻辑型
.局部变量 dwFlags, 整数型
.局部变量 strAgent, 文本型
.局部变量 hConnect, 整数型
.局部变量 hOpen, 整数型
.局部变量 szTemp, 文本型
.局部变量 dwSizeOfRq, 整数型
Onlined ＝ InternetGetConnectedState (dwFlags, 0)
.如果真 (Onlined ＝ 假)
  返回 (取文件名11 (地址))
.如果真结束
strAgent ＝ “我的下载” ＋ 到文本 (取启动时间 ())
.如果 (位与 (dwFlags, 4) ＝ 0)
  hOpen ＝ InternetOpenAHTTP (strAgent, 4, 0, 0, 0)
.否则
  hOpen ＝ InternetOpenAHTTP (strAgent, 0, 0, 0, 0)
.如果结束
.如果真 (hOpen ＝ 0)
  返回 (取文件名11 (地址))
.如果真结束
hConnect ＝ InternetOpenUrlAHTTP (hOpen, 地址, “”, 0, 2097152 ＋ 2147483648 ＋ 67108864 ＋ 256, 0)
.如果真 (hConnect ＝ 0)
  InternetCloseHandleHTTP (hOpen)
  返回 (取文件名11 (地址))
.如果真结束
szTemp ＝ 取空白文本 (255)
dwSizeOfRq ＝ 255
.如果真 (HttpQueryInfohx (hConnect, 51, szTemp, dwSizeOfRq, 0) ＝ 0)
  InternetCloseHandleHTTP (hOpen)
  返回 (取文件名11 (地址))
.如果真结束
InternetCloseHandleHTTP (hOpen)
返回 (取文件名11 (szTemp))
.子程序 取文件名11, 文本型
.参数 地址, 文本型
.局部变量 i, 整数型
.局部变量 szTemp, 文本型
szTemp ＝ 子文本替换 (地址, “\”, “/”, , , 真)
i ＝ 倒找文本 (szTemp, “/”, , 假)
.如果真 (i ≠ -1)
  szTemp ＝ 取文本右边 (szTemp, 取文本长度 (szTemp) － i)
.如果真结束
i ＝ 寻找文本 (szTemp, “?”, , 假)
.如果真 (i ＝ -1)
  返回 (szTemp)
.如果真结束
返回 (取文本左边 (szTemp, i － 1))
.子程序 文件_取扩展名, 文本型, 公开, 返回一个文件的后缀名,如：.jpg 如果没有后缀,返回空
.参数 文件名, 文本型, , 需要处理的原始文件名
返回 (PathFindExtensionAjtw (文件名))
.子程序 多线程_HTTP下载_开始_多任务, 整数型
.参数 参数_下载地址, 文本型
.参数 参数_保存路径, 文本型, , 可以只填写下载路径，程序将会以下载地址的文件名来保存，如果自己添加路径加文件名，则程序会将以自己添加的文件名来命名，注意：路径中不能有 . ，除非是添加路径加文件名
.参数 参数_线程数, 整数型
.参数 参数_回调函数地址, 整数型
.局部变量 变量_dwFlags, 整数型
.局部变量 变量_hOpen, 整数型
.局部变量 变量_szHead, 文本型
.局部变量 变量_hConnect, 整数型
.局部变量 变量_dwByteToRead, 整数型
.局部变量 变量_dwSizeOfRq, 整数型
.局部变量 变量_文件句柄, 整数型
.局部变量 变量_映射句柄, 整数型
.局部变量 变量_块, 整数型
.局部变量 变量_次数, 整数型
.局部变量 变量_hHeap, 整数型
.局部变量 变量_msg, 整数型
.局部变量 变量_地址, 整数型
.局部变量 变量_许可证, 整数型
.局部变量 变量_当前线程数, 整数型
.局部变量 变量_进程句柄, 整数型
.局部变量 c, 文本型, , "0"
.局部变量 a, 文本型
.局部变量 cc, 文本型
a ＝ 文件_取扩展名 (参数_保存路径)
.如果真 (a ＝ “”)
  .如果 (取文本右边 (参数_保存路径, 1) ＝ “\”)
    cc ＝ 文件_取网络文件名1 (参数_下载地址)
    参数_保存路径 ＝ 参数_保存路径 ＋ cc
  .否则
    cc ＝ 文件_取网络文件名1 (参数_下载地址)
    参数_保存路径 ＝ 参数_保存路径 ＋ “\” ＋ cc
  .如果结束
.如果真结束
.如果 (倒找文本 (参数_保存路径, “.”, , 假) ＝ -1) ' 那么就是 路径 ,没有文件名
  c ＝ 分割文本 (参数_保存路径, “\”, )
  .如果真 (取文本右边 (参数_保存路径, 1) ≠ “\”)
    参数_保存路径 ＝ 参数_保存路径 ＋ “\”
  .如果真结束
  参数_保存路径 ＝ 参数_保存路径 ＋ c [取数组成员数 (c)]
.否则
.如果结束
' 取文件大小
InternetGetConnectedStateHTTP (变量_dwFlags, 0)
.如果 (位与 (变量_dwFlags, 4) ＝ 0)
  变量_hOpen ＝ InternetOpenAHTTP (字符 (0), 4, 0, 0, 0)
.否则
  变量_hOpen ＝ InternetOpenAHTTP (字符 (0), 0, 0, 0, 0)
.如果结束
.如果真 (变量_hOpen ＝ 0)
  ' Internet连接错误
  返回 (-1)
.如果真结束
变量_szHead ＝ “Accept: */*” ＋ #换行符 ＋ “Accept-Language: zh-cn” ＋ #换行符 ＋ “Accept-Encoding: gzip, deflate” ＋ #换行符 ＋ “User-Agent: Mozilla/4.0(compatible; MSIE 6.0; Windows NT 5.0; MyIE2; .NET CLR 1.1.4322)”
变量_hConnect ＝ InternetOpenUrlAHTTP (变量_hOpen, 参数_下载地址, 变量_szHead, 取文本长度 (变量_szHead), 2214592768, 0)
.如果真 (变量_hConnect ＝ 0)
  ' 不能打开该URL!
  InternetCloseHandleHTTP (变量_hOpen)
  返回 (-1)
.如果真结束
变量_dwByteToRead ＝ 0
变量_dwSizeOfRq ＝ 4
.如果真 (HttpQueryInfoAHTTP (变量_hConnect, 536870917, 变量_dwByteToRead, 变量_dwSizeOfRq, 0) ＝ 0)
  变量_dwByteToRead ＝ 0
.如果真结束
InternetCloseHandleHTTP (变量_hConnect)
InternetCloseHandleHTTP (变量_hOpen)
' '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' 创建文件
变量_文件句柄 ＝ 创建文件 (参数_保存路径, 位或 (-2147483648, 1073741824), 位或 (1, 2), 0, 2, 0, 0)
.如果真 (变量_文件句柄 ＝ -1)
  返回 (-1)
.如果真结束
变量_映射句柄 ＝ 创建映射 (变量_文件句柄, 0, 4, 0, 变量_dwByteToRead, 0)
.如果真 (变量_映射句柄 ＝ 0)
  CloseHandleHTTP (变量_文件句柄)
  返回 (-1)
.如果真结束
.如果真 (变量_dwByteToRead ＝ 0)
  CloseHandleHTTP (变量_映射句柄)
  CloseHandleHTTP (变量_文件句柄)
  返回 (0)
.如果真结束
' ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' 计算分段
变量_块 ＝ 1024 × 1024
变量_次数 ＝ 变量_dwByteToRead ÷ 变量_块
.如果真 (变量_dwByteToRead ％ 变量_块 ≠ 0)
  变量_次数 ＝ 变量_次数 ＋ 1
.如果真结束
.如果真 (参数_线程数 ＞ 变量_次数)
  参数_线程数 ＝ 变量_次数
.如果真结束
' ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' 传递信息结构
变量_hHeap ＝ HeapCreate (4, 0, 0)
.如果真 (变量_hHeap ＝ 0)
  CloseHandleHTTP (变量_映射句柄)
  CloseHandleHTTP (变量_文件句柄)
  返回 (-1)
.如果真结束
' 下载地址指针，回调函数地址+4，文件句柄+8，映射句柄+12，堆+16，许可证指针+20，线程数+24，当前线程数+28，任务状态+32，块+36，当前次数+40，总次数+44，完成大小+48，文件大小+52，传递完毕+56
变量_msg ＝ HeapAllocHTTP (变量_hHeap, 8, 15 × 4)
.如果真 (变量_msg ＝ 0)
  HeapDestroy (变量_hHeap)
  CloseHandleHTTP (变量_映射句柄)
  CloseHandleHTTP (变量_文件句柄)
  返回 (-1)
.如果真结束
变量_地址 ＝ HeapAllocHTTP (变量_hHeap, 8, 取文本长度 (参数_下载地址) ＋ 1)
.如果真 (变量_地址 ＝ 0)
  HeapDestroy (变量_hHeap)
  CloseHandleHTTP (变量_映射句柄)
  CloseHandleHTTP (变量_文件句柄)
  返回 (-1)
.如果真结束
RtlMoveMemory_写文本 (变量_地址, 参数_下载地址, 取文本长度 (参数_下载地址) ＋ 1)
变量_许可证 ＝ HeapAllocHTTP (变量_hHeap, 8, 24)
.如果真 (变量_许可证 ＝ 0)
  HeapDestroy (变量_hHeap)
  CloseHandleHTTP (变量_映射句柄)
  CloseHandleHTTP (变量_文件句柄)
  返回 (-1)
.如果真结束
InitializeCriticalSectionHTTP (变量_许可证)
RtlMoveMemory_写整数 (变量_msg, 变量_地址, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 4, 参数_回调函数地址, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 8, 变量_文件句柄, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 12, 变量_映射句柄, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 16, 变量_hHeap, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 20, 变量_许可证, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 24, 参数_线程数, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 28, 变量_当前线程数, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 32, 0, 4) ' -1错误 0开始 1停止 2暂停
RtlMoveMemory_写整数 (变量_msg ＋ 36, 变量_块, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 40, 0, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 44, 变量_次数, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 48, 0, 4)
RtlMoveMemory_写整数 (变量_msg ＋ 52, 变量_dwByteToRead, 4)
' ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' 创建线程
变量_进程句柄 ＝ CreateThreadHTTP (0, 0, &HTTP下载处理_1_多任务, 变量_msg, 0, 0)
.如果真 (变量_进程句柄 ＝ 0)
  DeleteCriticalSectionHTTP (变量_许可证)
  HeapDestroy (变量_hHeap)
  CloseHandleHTTP (变量_映射句柄)
  CloseHandleHTTP (变量_文件句柄)
  返回 (-1)
.如果真结束
CloseHandleHTTP (变量_进程句柄)
返回 (变量_msg)
.子程序 多线程_HTTP下载_停止, , 公开
.参数 参数_句柄, 整数型
.局部变量 变量_许可证, 整数型
RtlMoveMemory_读整数 (变量_许可证, 参数_句柄 ＋ 20, 4)
EnterCriticalSectionHTTP (变量_许可证)
RtlMoveMemory_写整数 (参数_句柄 ＋ 32, 1, 4) ' -1错误 0开始 1停止 2暂停
LeaveCriticalSectionHTTP (变量_许可证)
.子程序 多线程_HTTP下载_暂停, , 公开
.参数 参数_句柄, 整数型
.局部变量 变量_许可证, 整数型
RtlMoveMemory_读整数 (变量_许可证, 参数_句柄 ＋ 20, 4)
EnterCriticalSectionHTTP (变量_许可证)
RtlMoveMemory_写整数 (参数_句柄 ＋ 32, 2, 4) ' -1错误 0开始 1停止 2暂停
LeaveCriticalSectionHTTP (变量_许可证)
.子程序 多线程_HTTP下载_继续, , 公开
.参数 参数_句柄, 整数型
.局部变量 变量_许可证, 整数型
RtlMoveMemory_读整数 (变量_许可证, 参数_句柄 ＋ 20, 4)
EnterCriticalSectionHTTP (变量_许可证)
RtlMoveMemory_写整数 (参数_句柄 ＋ 32, 0, 4) ' -1错误 0开始 1停止 2暂停
LeaveCriticalSectionHTTP (变量_许可证)
.子程序 HTTP下载处理_1_多任务
.参数 参数_信息指针, 整数型
.局部变量 变量_回调函数地址, 整数型
.局部变量 变量_文件句柄, 整数型
.局部变量 变量_映射句柄, 整数型
.局部变量 变量_堆, 整数型
.局部变量 变量_许可证, 整数型
.局部变量 变量_线程数, 整数型
.局部变量 变量_总次数, 整数型
.局部变量 变量_文件大小, 整数型
.局部变量 变量_当前次数, 整数型
.局部变量 变量_当前线程数, 整数型
.局部变量 变量_任务状态, 整数型
.局部变量 变量_进程句柄, 整数型
.局部变量 变量_传递完毕, 整数型
.局部变量 变量_完成大小, 整数型
.局部变量 i, 整数型
.局部变量 a, 文本型
.局部变量 传递ID, 整数型
' 下载地址指针，回调函数地址+4，文件句柄+8，映射句柄+12，堆+16，许可证指针+20，线程数+24，当前线程数+28，任务状态+32，块+36，当前次数+40，总次数+44，完成大小+48，文件大小+52，传递完毕+56
RtlMoveMemory_读整数 (变量_回调函数地址, 参数_信息指针 ＋ 4, 4)
RtlMoveMemory_读整数 (变量_文件句柄, 参数_信息指针 ＋ 8, 4)
RtlMoveMemory_读整数 (变量_映射句柄, 参数_信息指针 ＋ 12, 4)
RtlMoveMemory_读整数 (变量_堆, 参数_信息指针 ＋ 16, 4)
RtlMoveMemory_读整数 (变量_许可证, 参数_信息指针 ＋ 20, 4)
RtlMoveMemory_读整数 (变量_线程数, 参数_信息指针 ＋ 24, 4)
RtlMoveMemory_读整数 (变量_总次数, 参数_信息指针 ＋ 44, 4)
RtlMoveMemory_读整数 (变量_文件大小, 参数_信息指针 ＋ 52, 4)
变量_当前次数 ＝ 0
.判断循环首 (变量_当前次数 ＜ 变量_总次数)
  EnterCriticalSectionHTTP (变量_许可证)
  RtlMoveMemory_读整数 (变量_当前线程数, 参数_信息指针 ＋ 28, 4)
  LeaveCriticalSectionHTTP (变量_许可证)
  .如果真 (变量_当前线程数 ＜ 变量_线程数)
    EnterCriticalSectionHTTP (变量_许可证)
    RtlMoveMemory_读整数 (变量_任务状态, 参数_信息指针 ＋ 32, 4)
    LeaveCriticalSectionHTTP (变量_许可证)
    .如果真 (变量_任务状态 ＝ -1 或 变量_任务状态 ＝ 1)
      跳出循环 ()
    .如果真结束
    .如果真 (变量_任务状态 ＝ 2)
      WaitForSingleObjectHTTP (-1, 100)
      到循环尾 ()
    .如果真结束
    变量_当前次数 ＝ 变量_当前次数 ＋ 1
    RtlMoveMemory_写整数 (参数_信息指针 ＋ 40, 变量_当前次数, 4)
    变量_进程句柄 ＝ CreateThreadHTTP (0, 0, &HTTP下载处理_2_多任务, 参数_信息指针, 0, 0)
    .如果真 (变量_进程句柄 ＝ 0)
      EnterCriticalSectionHTTP (变量_许可证)
      RtlMoveMemory_写整数 (参数_信息指针 ＋ 32, -1, 4)
      LeaveCriticalSectionHTTP (变量_许可证)
      跳出循环 ()
    .如果真结束
    CloseHandleHTTP (变量_进程句柄)
    .循环判断首 ()
      EnterCriticalSectionHTTP (变量_许可证)
      RtlMoveMemory_读整数 (变量_传递完毕, 参数_信息指针 ＋ 56, 4)
      LeaveCriticalSectionHTTP (变量_许可证)
      WaitForSingleObjectHTTP (-1, 100)
    .循环判断尾 (变量_传递完毕 ＝ 0)
  .如果真结束
  WaitForSingleObjectHTTP (-1, 100)
.判断循环尾 ()
.循环判断首 ()
  EnterCriticalSectionHTTP (变量_许可证)
  RtlMoveMemory_读整数 (变量_当前线程数, 参数_信息指针 ＋ 28, 4)
  LeaveCriticalSectionHTTP (变量_许可证)
  WaitForSingleObjectHTTP (-1, 100)
.循环判断尾 (变量_当前线程数 ≠ 0)
RtlMoveMemory_读整数 (变量_任务状态, 参数_信息指针 ＋ 32, 4)
.判断开始 (变量_任务状态 ＝ -1)
  .计次循环首 (取数组成员数 (多任务句柄), i)
    .如果真 (参数_信息指针 ＝ 多任务句柄 [i])
      传递ID ＝ i
    .如果真结束
  .计次循环尾 ()
  .如果真 (传递ID ≠ 0)
    程序_Call (变量_回调函数地址, 传递ID, -1, 0, 0)
    ' 调用子程序 (变量_回调函数地址, , , 传递ID, -1, 0, 0)
  .如果真结束
.判断 (变量_任务状态 ＝ 0)
  RtlMoveMemory_读整数 (变量_完成大小, 参数_信息指针 ＋ 48, 4)
  .计次循环首 (取数组成员数 (多任务句柄), i)
    .如果真 (参数_信息指针 ＝ 多任务句柄 [i])
      传递ID ＝ i
    .如果真结束
  .计次循环尾 ()
  .如果真 (传递ID ≠ 0)
    程序_Call (变量_回调函数地址, 传递ID, 0, 变量_文件大小, 变量_完成大小)
    ' 调用子程序 (变量_回调函数地址, , , 传递ID, 0, 变量_文件大小, 变量_完成大小)
  .如果真结束
.默认
.判断结束
DeleteCriticalSectionHTTP (变量_许可证)
HeapDestroy (变量_堆)
CloseHandleHTTP (变量_映射句柄)
CloseHandleHTTP (变量_文件句柄)
.子程序 HTTP下载处理_2_多任务
.参数 参数_信息指针, 整数型
.局部变量 变量_下载地址指针, 整数型
.局部变量 变量_回调函数地址, 整数型
.局部变量 变量_映射句柄, 整数型
.局部变量 变量_许可证, 整数型
.局部变量 变量_堆, 整数型
.局部变量 变量_当前线程数, 整数型
.局部变量 变量_块_1, 整数型
.局部变量 变量_当前次数, 整数型
.局部变量 变量_总次数, 整数型
.局部变量 变量_文件大小, 整数型
.局部变量 变量_dwFlags, 整数型
.局部变量 变量_hOpen, 整数型
.局部变量 变量_szHead, 文本型
.局部变量 变量_开始, 整数型
.局部变量 变量_结尾, 整数型
.局部变量 变量_hConnect, 整数型
.局部变量 变量_块_2, 整数型
.局部变量 变量_http块, 整数型
.局部变量 变量_当前大小, 整数型
.局部变量 变量_szTemp, 整数型
.局部变量 变量_dwSize, 整数型
.局部变量 变量_写入位置, 整数型
.局部变量 变量_块位置, 整数型
.局部变量 变量_视图句柄, 整数型
.局部变量 变量_完成大小, 整数型
.局部变量 变量_任务状态, 整数型
.局部变量 i, 整数型
.局部变量 a, 文本型
.局部变量 传递ID, 整数型
' 下载地址指针，回调函数地址+4，文件句柄+8，映射句柄+12，堆+16，许可证指针+20，线程数+24，当前线程数+28，任务状态+32，块+36，当前次数+40，总次数+44，完成大小+48，文件大小+52，传递完毕+56
RtlMoveMemory_读整数 (变量_下载地址指针, 参数_信息指针, 4)
RtlMoveMemory_读整数 (变量_回调函数地址, 参数_信息指针 ＋ 4, 4)
RtlMoveMemory_读整数 (变量_映射句柄, 参数_信息指针 ＋ 12, 4)
RtlMoveMemory_读整数 (变量_堆, 参数_信息指针 ＋ 16, 4)
RtlMoveMemory_读整数 (变量_许可证, 参数_信息指针 ＋ 20, 4)
RtlMoveMemory_读整数 (变量_当前线程数, 参数_信息指针 ＋ 28, 4)
RtlMoveMemory_读整数 (变量_块_1, 参数_信息指针 ＋ 36, 4)
RtlMoveMemory_读整数 (变量_当前次数, 参数_信息指针 ＋ 40, 4)
RtlMoveMemory_读整数 (变量_文件大小, 参数_信息指针 ＋ 52, 4)
EnterCriticalSectionHTTP (变量_许可证)
RtlMoveMemory_读整数 (变量_当前线程数, 参数_信息指针 ＋ 28, 4)
RtlMoveMemory_写整数 (参数_信息指针 ＋ 28, 变量_当前线程数 ＋ 1, 4)
RtlMoveMemory_写整数 (参数_信息指针 ＋ 56, 1, 4)
LeaveCriticalSectionHTTP (变量_许可证)
InternetGetConnectedStateHTTP (变量_dwFlags, 0)
.如果 (位与 (变量_dwFlags, 4) ＝ 0)
  变量_hOpen ＝ InternetOpenAHTTP (字符 (0), 4, 0, 0, 0)
.否则
  变量_hOpen ＝ InternetOpenAHTTP (字符 (0), 0, 0, 0, 0)
.如果结束
.如果真 (变量_hOpen ＝ 0)
  ' Internet连接错误
  EnterCriticalSectionHTTP (变量_许可证)
  RtlMoveMemory_写整数 (参数_信息指针 ＋ 32, -1, 4)
  RtlMoveMemory_读整数 (变量_当前线程数, 参数_信息指针 ＋ 28, 4)
  RtlMoveMemory_写整数 (参数_信息指针 ＋ 28, 变量_当前线程数 － 1, 4)
  LeaveCriticalSectionHTTP (变量_许可证)
  返回 ()
.如果真结束
.如果 (变量_当前次数 ＝ 变量_总次数)
  变量_开始 ＝ 变量_块_1 × (变量_当前次数 － 1)
  变量_结尾 ＝ 变量_文件大小
.否则
  变量_开始 ＝ 变量_块_1 × (变量_当前次数 － 1)
  变量_结尾 ＝ 变量_块_1 × 变量_当前次数 － 1
.如果结束
变量_szHead ＝ “Accept: */*” ＋ #换行符 ＋ “Accept-Language: zh-cn” ＋ #换行符 ＋ “Accept-Encoding: gzip, deflate” ＋ #换行符 ＋ “User-Agent: Mozilla/4.0(compatible; MSIE 6.0; Windows NT 5.0; MyIE2; .NET CLR 1.1.4322)”
变量_szHead ＝ 变量_szHead ＋ #换行符 ＋ “Range:bytes=” ＋ 到文本 (变量_开始) ＋ “-” ＋ 到文本 (变量_结尾)
变量_hConnect ＝ InternetOpenUrlAHTTP (变量_hOpen, 指针到文本 (变量_下载地址指针), 变量_szHead, 取文本长度 (变量_szHead), 2214592768, 0)
.如果真 (变量_hConnect ＝ 0)
  ' 不能打开该URL!
  InternetCloseHandleHTTP (变量_hOpen)
  EnterCriticalSectionHTTP (变量_许可证)
  RtlMoveMemory_写整数 (参数_信息指针 ＋ 32, -1, 4)
  RtlMoveMemory_读整数 (变量_当前线程数, 参数_信息指针 ＋ 28, 4)
  RtlMoveMemory_写整数 (参数_信息指针 ＋ 28, 变量_当前线程数 － 1, 4)
  LeaveCriticalSectionHTTP (变量_许可证)
  返回 ()
.如果真结束
变量_块_2 ＝ 65536
变量_http块 ＝ 20480
变量_当前大小 ＝ 0
变量_szTemp ＝ HeapAllocHTTP (变量_堆, 8, 变量_http块)
.如果真 (变量_szTemp ＝ 0)
  InternetCloseHandleHTTP (变量_hConnect)
  InternetCloseHandleHTTP (变量_hOpen)
  EnterCriticalSectionHTTP (变量_许可证)
  RtlMoveMemory_写整数 (参数_信息指针 ＋ 32, -1, 4)
  RtlMoveMemory_读整数 (变量_当前线程数, 参数_信息指针 ＋ 28, 4)
  RtlMoveMemory_写整数 (参数_信息指针 ＋ 28, 变量_当前线程数 － 1, 4)
  LeaveCriticalSectionHTTP (变量_许可证)
  返回 ()
.如果真结束
.循环判断首 ()
  .如果真 (InternetReadFileHTTP (变量_hConnect, 变量_szTemp, 变量_http块, 变量_dwSize) ＝ 0)
    ' 读文件失败
    EnterCriticalSectionHTTP (变量_许可证)
    RtlMoveMemory_写整数 (参数_信息指针 ＋ 32, -1, 4)
    LeaveCriticalSectionHTTP (变量_许可证)
    跳出循环 ()
  .如果真结束
  .如果真 (变量_dwSize ＝ 0)
    跳出循环 ()
  .如果真结束
  变量_写入位置 ＝ 变量_开始 ＋ 变量_当前大小
  变量_块位置 ＝ 变量_写入位置 ÷ 变量_块_2
  变量_块位置 ＝ 变量_块位置 × 变量_块_2
  变量_视图句柄 ＝ 映射装载 (变量_映射句柄, 2, 0, 变量_块位置, 变量_写入位置 － 变量_块位置 ＋ 变量_dwSize)
  .如果真 (变量_视图句柄 ＝ 0)
    ' 映射装载失败
    EnterCriticalSectionHTTP (变量_许可证)
    RtlMoveMemory_写整数 (参数_信息指针 ＋ 32, -1, 4)
    LeaveCriticalSectionHTTP (变量_许可证)
    跳出循环 ()
  .如果真结束
  写入映射 (变量_视图句柄 ＋ 变量_写入位置 － 变量_块位置, 变量_szTemp, 变量_dwSize)
  映射卸载 (变量_视图句柄)
  变量_当前大小 ＝ 变量_当前大小 ＋ 变量_dwSize
  EnterCriticalSectionHTTP (变量_许可证)
  RtlMoveMemory_读整数 (变量_完成大小, 参数_信息指针 ＋ 48, 4)
  变量_完成大小 ＝ 变量_完成大小 ＋ 变量_dwSize
  RtlMoveMemory_写整数 (参数_信息指针 ＋ 48, 变量_完成大小, 4)
  ' 输出调试文本 (参数_信息指针)
  .计次循环首 (取数组成员数 (多任务句柄), i)
    .如果真 (参数_信息指针 ＝ 多任务句柄 [i])
      传递ID ＝ i
    .如果真结束
  .计次循环尾 ()
  .如果真 (传递ID ≠ 0)
    程序_Call (变量_回调函数地址, 传递ID, 1, 变量_文件大小, 变量_完成大小)
    ' 调用子程序 (变量_回调函数地址, , , 传递ID, 1, 变量_文件大小, 变量_完成大小)
  .如果真结束
  RtlMoveMemory_读整数 (变量_任务状态, 参数_信息指针 ＋ 32, 4)
  LeaveCriticalSectionHTTP (变量_许可证)
  .判断循环首 (变量_任务状态 ＝ 2)
    EnterCriticalSectionHTTP (变量_许可证)
    RtlMoveMemory_读整数 (变量_任务状态, 参数_信息指针 ＋ 32, 4)
    LeaveCriticalSectionHTTP (变量_许可证)
    .如果真 (变量_任务状态 ＝ -1 或 变量_任务状态 ＝ 1)
      跳出循环 ()
    .如果真结束
    WaitForSingleObjectHTTP (-1, 100)
  .判断循环尾 ()
.循环判断尾 (变量_任务状态 ≠ -1 且 变量_任务状态 ≠ 1)
HeapFree (变量_堆, 0, 变量_szTemp)
InternetCloseHandleHTTP (变量_hConnect)
InternetCloseHandleHTTP (变量_hOpen)
EnterCriticalSectionHTTP (变量_许可证)
RtlMoveMemory_读整数 (变量_当前线程数, 参数_信息指针 ＋ 28, 4)
RtlMoveMemory_写整数 (参数_信息指针 ＋ 28, 变量_当前线程数 － 1, 4)
LeaveCriticalSectionHTTP (变量_许可证)
.子程序 Call, 整数型, 公开
.参数 参数_地址, 整数型
.参数 参数_一, 整数型
.参数 参数_二, 整数型
.参数 参数_三, 整数型
置入代码 ({ 201, 88, 135, 4, 36, 255, 224 })
返回 (0)
.子程序 程序_Call, 整数型
.参数 子程序地址, 整数型
.参数 参数1, 整数型, 可空
.参数 参数2, 整数型, 可空
.参数 参数3, 整数型, 可空
.参数 参数4, 整数型, 可空
.参数 参数5, 整数型, 可空
.参数 参数6, 整数型, 可空
.参数 参数7, 整数型, 可空
.参数 参数8, 整数型, 可空
.参数 参数9, 整数型, 可空
.参数 参数10, 整数型, 可空
.参数 参数11, 整数型, 可空
.参数 参数12, 整数型, 可空
.参数 参数13, 整数型, 可空
.参数 参数14, 整数型, 可空
.参数 参数15, 整数型, 可空
置入代码 ({ 86, 190, 15, 0, 0, 0, 141, 77, 8, 141, 76, 241, 252, 139, 65, 4, 133, 192, 116, 2, 255, 49, 78, 131, 233, 8, 133, 246, 117, 239, 255, 85, 8, 94, 201, 194, 124, 0 })
返回 (0)

4.多任务下载

?
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
.版本 2
.程序集 下载_多任务, , 公开
.程序集变量 总计次, 整数型
.子程序 _初始化, , , 当基于本类的对象被创建后，此方法会被自动调用
总计次 ＝ 0
.子程序 _销毁, , , 当基于本类的对象被销毁前，此方法会被自动调用
.子程序 下载_多任务, , 公开
.参数 下载地址, 文本型
.参数 保存路径, 文本型
.参数 线程数, 整数型
.参数 回调函数地址, 整数型, 可空, 无返回值，传递ID=整数型，信息=整数型，文件大小=整数型，完成大小=整数型
.局部变量 a, 整数型
总计次 ＝ 总计次 ＋ 1
加入成员 (配备文本变量, 到文本 (总计次))
a ＝ 多线程_HTTP下载_开始_多任务 (下载地址, 保存路径, 线程数, 回调函数地址)
加入成员 (多任务句柄, a)
.子程序 暂停下载, , 公开
.参数 暂停ID, 整数型
多线程_HTTP下载_暂停 (多任务句柄 [暂停ID])
.子程序 全部暂停, , 公开
.局部变量 i, 整数型
.计次循环首 (取数组成员数 (多任务句柄), i)
  多线程_HTTP下载_暂停 (多任务句柄 [i])
.计次循环尾 ()
.子程序 停止下载
.参数 停止ID, 整数型
多线程_HTTP下载_停止 (多任务句柄 [停止ID])
.子程序 全部停止, , 公开
.局部变量 i, 整数型
.计次循环首 (取数组成员数 (多任务句柄), i)
  多线程_HTTP下载_停止 (多任务句柄 [i])
.计次循环尾 ()
.子程序 继续下载, , 公开
.参数 继续ID, 整数型
多线程_HTTP下载_继续 (多任务句柄 [继续ID])
.子程序 全部继续, , 公开
.局部变量 i, 整数型
.计次循环首 (取数组成员数 (多任务句柄), i)
  多线程_HTTP下载_继续 (多任务句柄 [i])
.计次循环尾 ()
.子程序 重试下载, , 公开
.参数 重试ID, 整数型
多线程_HTTP下载_停止 (多任务句柄 [重试ID])
多线程_HTTP下载_继续 (多任务句柄 [重试ID])
.子程序 全部重试, , 公开
.局部变量 i, 整数型
.计次循环首 (取数组成员数 (多任务句柄), i)
  多线程_HTTP下载_停止 (多任务句柄 [i])
  多线程_HTTP下载_继续 (多任务句柄 [i])
.计次循环尾 ()

以上是模块代码，下面是窗口程序集代码。

多线程多任务下载源码

需要加载上面的多线程多任务下载的模块

?
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
.版本 2
.支持库 iext
.程序集 窗口程序集1
.程序集变量 计次, 整数型
.程序集变量 下载, 下载_多任务
.程序集变量 速度1, 整数型
.程序集变量 速度2, 整数型
.子程序 内部回调, , 公开
.参数 传递ID, 整数型
.参数 信息
.参数 文件大小
.参数 完成大小
.局部变量 索引, 整数型
.局部变量 显示完成大小, 文本型
.局部变量 显示文件大小, 文本型
.如果真 (传递ID ＞ 3 或 传递ID ＜ 0)
  返回 ()
.如果真结束
.如果真 (传递ID ＝ 1)
  索引 ＝ 0
.如果真结束
.如果真 (传递ID ＝ 2)
  索引 ＝ 1
.如果真结束
.如果真 (传递ID ＝ 3)
  索引 ＝ 2
.如果真结束
.如果真 (四舍五入 (完成大小, 1) ＜ 1024)
  显示文件大小 ＝ 到文本 (四舍五入 (文件大小, 1)) ＋ “ Byte”
.如果真结束
.如果真 (四舍五入 (完成大小, 1) ＞ 1024)
  显示文件大小 ＝ 到文本 (四舍五入 (文件大小 ÷ 1024, 1)) ＋ “ KB”
.如果真结束
.如果真 (四舍五入 (完成大小 ÷ 1024, 1) ＞ 1024)
  显示文件大小 ＝ 到文本 (四舍五入 (文件大小 ÷ 1024 ÷ 1024, 1)) ＋ “ MB”
.如果真结束
.如果真 (四舍五入 (文件大小 ÷ 1024 ÷ 1024, 1) ＞ 1024)
  显示文件大小 ＝ 到文本 (四舍五入 (文件大小 ÷ 1024 ÷ 1024 ÷ 1024, 1)) ＋ “ GB”
.如果真结束
.如果真 (四舍五入 (完成大小, 1) ＜ 1024)
  显示完成大小 ＝ 到文本 (四舍五入 (完成大小, 1)) ＋ “ Byte”
.如果真结束
.如果真 (四舍五入 (完成大小, 1) ＞ 1024)
  显示完成大小 ＝ 到文本 (四舍五入 (完成大小 ÷ 1024, 1)) ＋ “ KB”
.如果真结束
.如果真 (四舍五入 (完成大小 ÷ 1024, 1) ＞ 1024)
  显示完成大小 ＝ 到文本 (四舍五入 (完成大小 ÷ 1024 ÷ 1024, 1)) ＋ “ MB”
.如果真结束
.如果真 (四舍五入 (完成大小 ÷ 1024 ÷ 1024, 1) ＞ 1024)
  显示完成大小 ＝ 到文本 (四舍五入 (完成大小 ÷ 1024 ÷ 1024 ÷ 1024, 1)) ＋ “ GB”
.如果真结束
超级列表框1.置标题 (索引, 2, 显示完成大小)
超级列表框1.置标题 (索引, 3, 显示文件大小)
超级列表框1.置标题 (索引, 4, 到文本 (到整数 (完成大小 ÷ 文件大小 × 100)) ＋ “%”)
超级列表框1.置标题 (索引, 5, “下载中”)
.子程序 _下载按钮_被单击
.局部变量 索引, 整数型
.如果真 (输入编辑框.内容 ＝ “”)
  返回 ()
.如果真结束
下载.下载_多任务 (输入编辑框.内容, “C:\Users\Administrator\Desktop\” ＋ 取网络文件名称 (输入编辑框.内容), 10, 到整数 (&内部回调))
计次 ＝ 计次 ＋ 1
索引 ＝ 超级列表框1.插入表项 (, , , , , )
超级列表框1.置标题 (索引, 0, 到文本 (计次))
超级列表框1.置标题 (索引, 1, 取网络文件名称 (输入编辑框.内容))
.子程序 程序_Call, 整数型
.参数 子程序地址, 整数型
.参数 参数1, 整数型, 可空
.参数 参数2, 整数型, 可空
.参数 参数3, 整数型, 可空
.参数 参数4, 整数型, 可空
.参数 参数5, 整数型, 可空
.参数 参数6, 整数型, 可空
.参数 参数7, 整数型, 可空
.参数 参数8, 整数型, 可空
.参数 参数9, 整数型, 可空
.参数 参数10, 整数型, 可空
.参数 参数11, 整数型, 可空
.参数 参数12, 整数型, 可空
.参数 参数13, 整数型, 可空
.参数 参数14, 整数型, 可空
.参数 参数15, 整数型, 可空
置入代码 ({ 86, 190, 15, 0, 0, 0, 141, 77, 8, 141, 76, 241, 252, 139, 65, 4, 133, 192, 116, 2, 255, 49, 78, 131, 233, 8, 133, 246, 117, 239, 255, 85, 8, 94, 201, 194, 124, 0 })
返回 (0)
.子程序 取网络文件名称, 文本型
.参数 路径, 文本型
.局部变量 a, 文本型, , "0"
a ＝ 分割文本 (路径, “/”, )
返回 (a [取数组成员数 (a)])
.子程序 _标签1_鼠标左键被放开, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
置剪辑板文本 (标签1.标题)
输入编辑框.内容 ＝ 标签1.标题
.子程序 _标签2_鼠标左键被放开, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
置剪辑板文本 (标签2.标题)
输入编辑框.内容 ＝ 标签2.标题
.子程序 _标签3_鼠标左键被放开, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
置剪辑板文本 (标签3.标题)
输入编辑框.内容 ＝ 标签3.标题
.子程序 _暂停按钮_被单击
下载.全部暂停 ()
.子程序 _继续下载按钮_被单击
下载.全部继续 ()
.子程序 _停止按钮_被单击
下载.全部停止 ()

运行结果：

易语言多线程多任务下载器的代码

总结

以上就是这篇文章的全部内容了，希望本文的内容对大家的学习或者工作具有一定的参考学习价值，谢谢大家对米米素材网的支持。如果你想了解更多相关内容请查看下面相关链接